Многократное выполнение однотипных запросов

#std436

Область применения: управляемое приложение, мобильное приложение, обычное приложение.

1. Рекомендуется получать все необходимые однотипные данные одним запросом, вместо выполнения серии запросов. Это ускоряет исполнение запроса к базе данных. Для объединения запросов в один используются, например, условия В, ключевое слово ОБЪЕДИНИТЬ ВСЕ и пакет запросов.

Правильно:

ОбщийЗапрос = Новый Запрос("
|ВЫБРАТЬ
| БанковскиеСчета.Ссылка КАК Счет
|ИЗ
| Справочник.БанковскиеСчета КАК БанковскиеСчета
|ГДЕ
| БанковскиеСчета.Банк В(&БанкиДляОбработки)");

ОбщийЗапрос.УстановитьПараметр("БанкиДляОбработки", БанкиДляОбработки);
ВыборкаСчетов = ОбщийЗапрос.Выполнить().Выбрать();
Пока ВыборкаСчетов.Следующий() Цикл
ОбработатьСчетаВБанке(ВыборкаСчетов.Счет);
КонецЦикла;

Неправильно:

ЧастныйЗапрос = Новый Запрос("
|ВЫБРАТЬ
| БанковскиеСчета.Ссылка КАК Счет
|ИЗ
| Справочник.БанковскиеСчета КАК БанковскиеСчета
|ГДЕ
| БанковскиеСчета.Банк = &Банк");

Для каждого Банк Из БанкиДляОбработки Цикл
ЧастныйЗапрос.УстановитьПараметр("Банк", Банк);
ВыборкаСчетов = ЧастныйЗапрос.Выполнить().Выбрать();
Пока ВыборкаСчетов.Следующий() Цикл
ОбработатьСчетаВБанке(ВыборкаСчетов.Счет);
КонецЦикла;
КонецЦикла;

При использовании Библиотеки стандартных подсистем (БСП) правильно вызывать программный интерфейс, предназначенный для работы со списками объектов, например, однократно вызывать функцию ОбщегоНазначения.ЗначениеРеквизитаОбъектов вместо ЗначениеРеквизитаОбъекта в цикле, УправлениеКонтактнойИнформацией.КонтактнаяИнформацияОбъектов вместо КонтактнаяИнформацияОбъекта в цикле.

2. Допускается разделение запроса на серию запросов в следующих случаях:

заметное усложнение разработки запроса для выбора сразу всех однотипных данных;
деградация производительности запроса. Например, когда запрос содержит обращение к виртуальным таблицам, формируемым на определенную дату (как в случае с виртуальными таблицами остатков регистра накопления, срезом последних периодического регистра сведений и т.п.);
порционная обработка большого объема данных
- в обработчиках обновления;
- в групповом проведении, изменении данных, удалении помеченных объектов, контроле ведения учета и т.п.;
- при загрузке данных из файла или внешних источников, получении почты и т.п.

В этих случаях запросы в цикле:

необходимы для порционности;
либо они незначительно замедляют по сравнению с записью самих данных;
либо они неустранимы на текущих средствах платформы (например, чтение и запись наборов регистра в цикле по значениям измерения).

3. Запросы к разным таблицам также рекомендуется объединять в один с помощью ОБЪЕДИНИТЬ ВСЕ или пакета запросов. Однако, выигрыш во времени исполнения может оказаться незначительным.