Особенности использования свойства ОбратныйАдрес почтового сообщения

Если значение свойства ОбратныйАдрес объекта ИнтернетПочтовоеСообщение установлено, оно указывает на почтовые адреса, на которые автор сообщения хотел бы получить ответ. В случае если свойство ОбратныйАдрес не заполнено, по умолчанию ответ должен отсылаться по адресу находящемуся в свойстве Отправитель.

Ниже приведен небольшой пример использования свойства ОбратныйАдрес. В примере выполняется получение всех сообщений, создание и отправка отчета о получении:

    Почта = Новый ИнтернетПочта;
    // Настраиваем профиль
    Профиль = Новый ИнтернетПочтовыйПрофиль;
    Профиль.АдресСервераPOP3 = "pop3.foobar.org";
    Профиль.АдресСервераSMTP = "smtp.foobar.org";
    Профиль.Пользователь = "user";
    Профиль.Пароль = "password";
    Почта.Подключиться(Профиль);
    
    // Получаем все сообщения
    МассивПисем = Почта.Выбрать(Ложь);
    Для Каждого Письмо из МассивПисем Цикл
        
        // Создаем ответное сообщение о получении
        ОтправляемоеСообщение = Новый ИнтернетПочтовоеСообщение;
        ОтправляемоеСообщение.Тема = "Письмо получено.";
        ОтправляемоеСообщение.Кодировка = "koi8-r";
        
        // Если присутствует обратный адрес, значит отправляем
        // по нему, т.к. автор сообщения желал получить отчет
        // о получении именно по этому адресу.
        Если (Письмо.ОбратныйАдрес.Количество() > 0) Тогда 
            Для Каждого АдресДляОтвета из Письмо.ОбратныйАдрес Цикл
                ОтправляемоеСообщение.Получатели.Добавить(АдресДляОтвета.Адрес);
            КонецЦикла;
        Иначе
            ОтправляемоеСообщение.Получатели.Добавить(Письмо.Отправитель.Адрес);
        КонецЕсли;
        
        Почта.Послать(ОтправляемоеСообщение);
        
    КонецЦикла;
    
    Почта.Отключиться();